Не удается установить REST аддон

Вопросы и проблемы
1

Добрый день!
Не удается установить REST ни через маркетплейс, ли просто вводом зависимости.

Если устанавливать через маркетплейс, то выдается ошибка:
```
Add-on artifacts are not found. Please specify required repository.

Not found dependencies:
io.jmix.security:jmix-security-oauth2-starter
```

если добавить зависимость oauth2, то выдает ошибку
```

Diploma:main: Could not find io.jmix.security:jmix-security-oauth2-starter:. Required by: root project :

Possible solution:

```

Если просто вставить строчку зависимости REST, выдает аналоигчную ошибку выше, не находит.

```

plugins {
    id 'io.jmix' version '2.6.2'
    id 'java'
    id 'org.jetbrains.gradle.plugin.idea-ext' version '1.1.9'
}

apply plugin: 'org.springframework.boot'
apply plugin: 'com.vaadin'

jmix {
    bomVersion = '2.6.2'
}

group = 'com.company'
version = '0.0.1-SNAPSHOT'

repositories {
    mavenCentral()
    maven {
        url = 'https://global.repo.jmix.io/repository/public'
    }
    maven {
        url = 'https://global.repo.jmix.io/repository/premium'
        credentials {
            username = rootProject['premiumRepoUser']
            password = rootProject['premiumRepoPass']
        }
    }
}

dependencies {
    implementation 'io.jmix.bpm:jmix-bpm-starter'
    implementation 'io.jmix.bpm:jmix-bpm-flowui-starter'

    implementation 'io.jmix.core:jmix-core-starter'
    implementation 'io.jmix.data:jmix-eclipselink-starter'
    implementation 'io.jmix.security:jmix-security-starter'
    implementation 'io.jmix.security:jmix-security-flowui-starter'
    implementation 'io.jmix.security:jmix-security-data-starter'
    implementation 'io.jmix.localfs:jmix-localfs-starter'
    implementation 'io.jmix.flowui:jmix-flowui-starter'
    implementation 'io.jmix.flowui:jmix-flowui-data-starter'
    implementation 'io.jmix.flowui:jmix-flowui-themes'
    implementation 'io.jmix.datatools:jmix-datatools-starter'
    implementation 'io.jmix.datatools:jmix-datatools-flowui-starter'

    implementation 'org.springframework.boot:spring-boot-starter-web'

    implementation 'org.postgresql:postgresql'

    implementation 'org.apache.poi:poi:5.2.5'
    implementation 'org.apache.poi:poi-ooxml:5.4.0'

    testImplementation('org.springframework.boot:spring-boot-starter-test') {
        exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
    }
    testImplementation 'io.jmix.flowui:jmix-flowui-test-assist'
}

configurations.implementation {
    exclude group: 'com.vaadin', module: 'hilla'
    exclude group: 'com.vaadin', module: 'hilla-dev'
    exclude group: 'com.vaadin', module: 'copilot'
}

test {
    useJUnitPlatform()
}

idea {
    module {
        excludeDirs.addAll(files '.jmix', 'node_modules', 'src/main/frontend/generated/', 'src/main/bundles')
    }
}

vaadin {
    optimizeBundle = false
    productionMode = true
}

```
BPMN модуль, к примеру, работает без нареканий, аунтефикация успешна.

Вот код проекта: GitHub - Holeriia/Diploma · GitHub
Jmix version: 2.6.2
Jmix Studio Plugin Version: 2.6.4-252
IntelliJ version: IntelliJ IDEA 2025.2.1 (Community Edition)

2

Здравствуйте!

Для Jmix 2.6 в стандартном варианте использования с авторизацией токенами вам нужно добавить две зависимости:

implementation 'io.jmix.rest:jmix-rest-starter'
implementation 'io.jmix.authserver:jmix-authserver-starter'

См. https://docs.jmix.ru/jmix/2.6/rest/index.html, https://docs.jmix.ru/jmix/2.6/rest/getting-started.html.

С уважением,
Константин